萧青荷出品 少林易经超级宏 V32.6版本

　　1.转载的青荷大大的宏!

　　2.换武器请删除多余的武器名字

　　3.按键频率建议超过一秒3次(不一定要按键精灵，手速也可以达到这个速度)

　　4.请三段及以上加速的和尚、延迟超过150的和尚使用非预判模式、延迟超过100不建议换水武器，否则会出现一直拿水武器打技能的情况

　　V32.6

　　1.调整三刀流/雷-普通武器切换模块，默认的三刀流中普通武器名字中去掉两把雷武器名字

　　2.修正触发时间判定，雷属性触发时间跟CW一样由触发的开始时间来确定了

　　V32.5

　　1.微调苏曼莎捉影式拉怪的判定，只拉距离内的怪

　　V32.4

　　1.血战天策的战字写错了。

　　V32.3

　　1.发现一个超级宏的BUG，导致连减无法识别，加个括号解决问题。因此导致的智能爆发的BUG彻底修正，已通过测试。

　　V32.2

　　1.血量大于500W的小怪默认判定为BOSS

　　2.智能爆发BUG修正

　　3.新的换武器模式，欢迎雷普通武器、雷CW、三刀流玩家测试

　　* 当换武器模式选择为雷武器切换并且被切换武器是CW的时候

　　【CW-雷模式】CW作为主武器输出，雷武器只在GCD时切出来打六合棍触发雷buff

　　* 当换武器模式选择为雷武器切换并且被切换武器是普通武器(相对于CW而言)的时候

　　【雷-普通模式】开怪使用雷武器作为主武器输出，雷buff触发时候换回普通武器直到雷的内置CD(距离上次触发一分钟)好了之后再切换至雷武器触发buff，如此循环

　　* 三刀流切换

　　水武器切换模式不变，雷buff的切换模式类同于【雷-普通】模式

　　#name 易经宏

　　#tip 作者：萧青荷/电六N合一。一个专业奶秀写的易经宏，需要修改自行看注释，如有问题请密我QQ/YY或者直接来电六密我。

　　#hello $name，欢迎使用超级宏，目前版本为32.6，如有问题请在超级宏官网找我的联系方式。

　　#icon 4930

　　#delay 1

　　#VarBool v_自动使用腰坠,tip:特效腰坠,tip_1:使用腰坠,tip_2:不使用腰坠,icon:2841

　　#VarNum v_预判开关,2,tip:预判开关,tip_1:开启预判,tip_2:关闭预判,icon_1:6016,icon_2:1817

　　#VarNum v_小怪处理,2,tip:小怪处理,tip_1:小怪可开爆发,tip_2:小怪不开爆发,icon_1:5356,icon_2:1817

　　#VarNum v_爆发模式,4,tip:爆发模式,tip_1:智能爆发,tip_2:自动爆发,tip_3:辅助开腰坠,tip_4:不开爆发,icon_1:5397,icon_2:5396,icon_3:5399,icon_4:1817

　　#VarNum v_金刚怒目,2,tip:金刚怒目模式,tip_1:全程保持,tip_2:百分之三十血不打金刚怒目,icon_1:440,icon_2:1817

　　#VarNum v_副本定制,3,tip:副本定制,tip_1:开,tip_2:关,tip_3:全程扶摇,icon_1:4544,icon_2:4553,icon_3:3549

　　#VarNum v_橙武模式,2,tip:橙武buff使用,tip_1:韦陀拿云交替,tip_2:无限韦陀,icon_1:428,icon_2:419

　　#varnum v_自动换武器,4,tip:换武器,tip_1:没武器可换,tip_2:水特效,tip_3:雷特效,tip_4:三刀流,icon_1:5935,icon_2:3976,icon_3:4779,icon_4:4930

　　#skillbox 韦陀献杵,无相诀,擒龙诀,亦枯亦荣,横扫六合,捉影式,扶摇直上,般若诀

　　--★打断模式开关★

　　--1:打断

　　--2:不打断

　　/var [1]v_自动打断

　　--★守缺优先开关★

　　--守缺优先级正式丢出开关(再加开关开关就太多了，这个应该不常调)

　　--1:非三豆先横扫后守缺

　　--2:非三豆优先守缺

　　--3:两豆不丢守缺

　　--4:三豆丢守缺

　　/var [1]v_守缺优先

　　--★通用变量★

　　--目标类型为BOSS的怪物判定为BOSS，其他为小怪

　　/if [target:boss;v_小怪处理=1;tname:木桩;tmaxlife>=5000000]

　　/var [false]v_小怪判定

　　/else

　　/var [true]v_小怪判定

　　/end

　　--禁韦陀判定，点了断灭，并且目标周围有不能群的小怪

　　/var [false]v_禁断灭

　　--禁横扫判定，自身周围有不能群的小怪

　　/var [false]v_禁横扫

　　--禁攻击判定，目标不能打，自动停手

　　/var [false]v_禁攻击

　　--禁爆发判定，目标身上有吸伤害盾/无敌buff等

　　/var [false]v_禁爆发

　　/if [!fight;!v_雷触发时间]

　　/var [0]v_雷触发时间

　　/end

　　/if [!fight;!v_CW触发时间]

　　/var [0]v_CW触发时间

　　/end

　　--雷buff内置CD,可调整

　　/var [60]v_雷buff内置CD

　　--上一次触发雷buff的时间，用于智能爆发

　　/if [buff:4759,(!v_雷触发时间;nowtime-v_雷触发时间>16)]

　　/var [nowtime]v_雷触发时间

　　/end

　　--CWbuff内置CD,可调整

　　/var [30]v_CWbuff内置CD

　　--上一次触发CWbuff的时间，用于智能爆发

　　/if [buff:1919,(!v_CW触发时间;nowtime-v_CW触发时间>7)]

　　/var [nowtime]v_CW触发时间

　　/end

　　--★剑圣划水模式★

　　/if [tplate:剑圣,fight,dis>12]

　　/skill 捕风式,捉影式

　　/skill [nav>=3]金刚怒目

　　/return

　　/end

　　--★自动QTE★

　　/skill QTE

　　--★检测换武器模式★

　　--1.CW模式下,CW作为主武器进行输出,在GCD时换雷武器打六合棍触发雷buff,仅适用于CW与雷武器的切换

　　--2.雷普通武器模式下,正常情况下使用普通武器进行输出,在雷的内置CD到的时候使用雷武器进行输出并触发雷buff,适用于雷-普通武器切换及三刀流

　　/if [!fight]

　　/var [false]v_CW雷武器模式

　　/end

　　/if [v_自动换武器=3]

　　--雷武器切换

　　/if [bag:燃木|龙木金藤;equip:燃木|龙木金藤]

　　/var [true]v_CW雷武器模式

　　/end

　　/end

　　--★换武器，如嫌繁琐，请自行将自己没有的武器删掉★

　　/if [v_自动换武器=2]

　　/if [buff:水·痛切<10;cd0>0.2+ping;bufftime:水·痛切<=2]

　　/omwp 禅心伏明

　　/else

　　/omwp 白塔思,菩提擀面杖·火候,丙涅禅杖,禅机棍,寂净谛观,顽石问路,心禅,惟清·木缪杖,杳冥棍,枕维棍,妙行无量,龙木金藤,燃木

　　/end

　　/elseif [v_自动换武器=3,!v_CW雷武器模式]

　　--普通武器/雷武器模式,正常时候使用普通武器打,雷buff内置CD到了之后再用雷武器打

　　/if [nobuff:6394,!v_小怪判定,(v_雷触发时间=0;(nowtime-v_雷触发时间)-v_雷buff内置CD>0)]

　　/omwp 寂净谛观,妙行无量

　　/else

　　/omwp 禅机棍,顽石问路,心禅,惟清·木缪杖,杳冥棍,枕维棍

　　/end

　　/elseif [v_自动换武器=3,v_CW雷武器模式]

　　--橙武雷模式:GCD的时候使用CW,其他时候打六合棍

　　/if [nobuff:6394,cd0>0.2+ping,!v_小怪判定]

　　/omwp 寂净谛观,妙行无量

　　/else

　　/omwp 龙木金藤,燃木

　　/end

　　/elseif [v_自动换武器=4]

　　/if [buff:水·痛切<10;cd0>0.2+ping;bufftime:水·痛切<=2]

　　/omwp 禅心伏明

　　/elseif [nobuff:6394,!v_小怪判定,(v_雷触发时间=0;(nowtime-v_雷触发时间)-v_雷buff内置CD>0)]

　　/omwp 寂净谛观,妙行无量

　　/else

　　/omwp 禅机棍,顽石问路,心禅,惟清·木缪杖,杳冥棍,枕维棍,龙木金藤,燃木

　　/end

　　/end

　　/if [v_副本定制=1;v_副本定制=3]

　　--★各副本定制★

　　--分副本地图进行判断,避免过多无用判断造成效率降低

　　--★秦皇陵★

　　/if [mapc:秦皇陵]

　　--老一,接近下P2的时候自动扶摇,躲车

　　/skill [target:王翦,tlife>=0.5,tlife<=0.82]扶摇直上

　　--★风雪稻香村★

　　--老一，老一出现时自动切换到老一身上，暗杀者并且读条无人打断时，自动使用捉影式

　　/elseif[mapc:风雪稻香村]

　　/tab [tprepare<0.7,tplate:隐元会暗杀者,tmfront,dis>4]npc

　　/skill [tprepare<0.7,tplate:隐元会暗杀者]捉影式

　　/tab [tplate:地字一号]npc

　　/skill [tplate:地字一号,tlife<=0.2]扶摇直上

　　--老三，暂缺，等待打法成熟

　　--★血战天策★

　　/elseif [mapc:血战天策]

　　--老一,小怪打断,火星自动补扶摇,跳河自动删除扶摇buff/自动锻骨诀

　　/skill [v_自动打断=1,tprepare:急行军] 抢珠式

　　/if [tplate:席庶云]

　　/skill [buff:火星]扶摇直上

　　/skill [tpre:云烟卷>0.6] 锻骨诀

　　/delbuff [tpre:云烟卷] 弹跳

　　--老三,山狼曹炎烈,排云箭自动减伤

　　/elseif [tplate:曹炎烈]

　　/skill [tpre:散花排云箭>0.5]无相诀

　　--老五,雷狼沙叱博

　　--狼之怒和藏离精失

　　/elseif [tplate:沙叱博]

　　/skill [tlife<0.31;tlife>0.7,tlife<0.72;tpre:狼之怒] 扶摇直上

　　/skill [tpre:狼之怒|藏离精失]无相诀

　　/else

　　--老七,黑齿元佑

　　--自动选择距离最近的小怪，如果在小怪阶段误选黑齿元佑则自动清空目标

　　/tab [texistnpc:黑齿元佑,tplate:黑齿卫士|黑齿巫师|黑齿祭司,tmfront]npc,dismin

　　/skill [texistnpc:黑齿卫士|黑齿巫师|黑齿祭司,tplate:黑齿元佑]清空目标

　　--老八,苏曼莎

　　--自动选择距离最近/正面的狼牙巫医捉影式

　　/tab [texistnpc:杨宁,tplate:狼牙巫医,tmfront,dis<=20,dis>10]npc,dismin

　　/skill [tplate:狼牙巫医,dis>10]捉影式

　　/end

　　--★大明宫★

　　/elseif [mapc:大明宫]

　　/skill [tplate:何莘涯,nobuff:镇山河,tprepare:吞云吐纳>0.7,dis<8] 后撤

　　/skill [v_自动打断=1,tprepare:怒吼] 抢珠式

　　/skill [fight,(tpre:皇之怒;buff:沙暴;tplate:独孤问俗,tlife<0.13;tplate:无名,tbuff:白昼;tplate:安禄山,(tlife>0.7,fight>15;tlife<0.12);tplate:头狼)] 扶摇直上

　　--★军械库★

　　/elseif [mapc:军械库]

　　/skill [tplate:卓力格图,nobuff:镇山河,tprepare:掷锤>0.5] 后撤

　　--★南诏皇宫★

　　/elseif [mapc:南诏皇宫]

　　--李倓保持扶摇

　　/skill [fight,tplate:李倓,tlife>0.2] 扶摇直上

　　/else

　　--需要打断的情况下抢珠

　　/skill [v_自动打断=1,tprepare:无懈可击|**化物|雨钓江秋|火舞金钢|阴阳双流|龙甩尾|薛家剑法] 抢珠式

　　/end

　　/end

　　--★自动补般若★

　　/skill [nobuff:般若诀,nobuff:1919]般若诀

　　--危险状态下，开无相

　　/skill [life<0.4,fight,nobuff:渊&镇山河&春泥护花&圣手织天&蝶戏水&天地低昂&舍身]无相诀

　　/return [!tar]

　　--佛心好了就开

　　/skill [fight,nobuff:九襄地玄五阵&金刚伏魔五阵&引羌笛&极乐]佛心诀

　　--有CWBUFF，众嗔buff快断了，补众嗔(优先级第一)

　　/skill [buff:1919,cdtime:守缺式<0.2,sklv:6596=1,(bufftime:众嗔;3)<2]守缺式

　　/skill [v_副本定制=3]扶摇直上

　　--★橙武处理★

　　/if [v_橙武模式=2]

　　--有CWBUFF，无限韦陀

　　/skill [!v_禁断灭,buff:1919]韦陀献杵

　　/elseif [v_橙武模式=1]

　　--有CWBUFF，交替韦陀拿云

　　/skill [buff:1919,nav=3]拿云式

　　/skill [!v_禁断灭,buff:1919]韦陀献杵

　　/end

　　--★起手处理★

　　--开怪首先金刚怒目消耗掉豆，然后守缺式

　　/skill [nobuff:1919,nobuff:守缺,sktest:守缺式,cdtime:守缺式<0.2,nav=3,cdtime:金刚怒目<0.2]金刚怒目

　　/skill [nobuff:守缺,cdtime:守缺式<0.2] 守缺式

　　--★群攻部分★

　　--点了断灭的情况下，如果6尺范围内的怪物超过2只，释放韦陀献杵

　　/skill [!v_禁断灭,sklv:断灭=1,temdis:6>2,nav=3] 韦陀献杵

　　--★腰坠★

　　--1【智能爆发】模式下配合擒龙诀使用腰坠

　　--2【无脑爆发】无脑使用腰坠

　　--3【辅助开腰坠】模式下手动擒龙，见擒龙开爆发，腰坠的判定上等同于1

　　/skill [!v_爆发模式=4,buff:擒龙诀,v_自动使用腰坠,!v_小怪判定]腰坠

　　--★★预判版宏★★

　　/if [v_预判开关=1]

　　--记录禅那，之所以记录禅那，是因为放了技能之后，下一个技能就已经准备好释放了，那时候判断禅那会有一定延迟

　　/var [nav] v_nav

　　--★无GCD技能部分★

　　--无相诀之后不开爆发

　　/if [!expcast:无相诀]

　　--优先金刚怒目，后擒龙诀

　　/skill [v_nav=3,fight,tlife<1,sktest:守缺式,cdtime:金刚怒目<0.2,nobuff:1919,(v_金刚怒目=1;tlife>0.3)]金刚怒目

　　/var [sklv:金刚怒目>0,explast:金刚怒目,0;v_nav]v_nav--释放金刚怒目之后，禅那归零

　　--GCD在读到接近一半的时候，再开擒龙诀，此后，每次刷到一半就会回一个豆，判定可以很精确

　　--请勿随意调整GCD的判定数据，否则会造成预判不准在非三豆的情况下打韦陀、拿云

　　--1【智能爆发】如果CWbuff的内置CD小于20秒，擒龙好了，则等待buff触发再打擒龙/雷buff的内置CD小于20秒，擒龙好了，则等待buff触发再打擒龙

　　--2【自动爆发】直接使用擒龙诀

　　/if [!banskill:擒龙诀,cd0<0.9,cd0>0.5,fight,sktest:守缺式,cdtime:擒龙诀<0.2,!v_小怪判定,(v_爆发模式=2;v_爆发模式=1,(v_雷触发时间=0,v_CW触发时间=0;(nowtime-v_雷触发时间)-v_雷buff内置CD<-30;(nowtime-v_CW触发时间)-v_CWbuff内置CD<-15))]

　　/skill [v_nav=1,fight,cdtime:亦枯亦荣<0.2,nowtime-(v_终结技释放标志;0)<1.5] 亦枯亦荣,擒龙诀

　　/skill [v_nav<=1]擒龙诀

　　/end

　　/var [explast:擒龙诀,3;v_nav]v_nav--释放擒龙诀之后，禅那变成3

　　--擒龙诀之后，如果金刚怒目好了，优先金刚怒目

　　/skill [v_nav=3,fight,tlife<1,sktest:守缺式,cdtime:金刚怒目<0.2,nobuff:1919,(v_金刚怒目=1;tlife>0.3)]金刚怒目

　　/var [sklv:金刚怒目>0,explast:金刚怒目,0;v_nav]v_nav--释放金刚怒目之后，禅那归零

　　/end

　　--有捕风式buff或者GCD大于0.5秒的，并且可以释放捉影式的时候，释放捉影式

　　/skill [!tplate:地字一号|隐元会暗杀者,!texistnpc:杨宁,(v_nav<3,(buff:捕风式;gcd>0.5),cdtime:捉影式<0.2)] 捉影式

　　/var [explast:捉影式,v_nav+1;v_nav]v_nav

　　--缺蓝就不等擒龙诀，直接开亦枯亦荣了

　　/skill [mana<0.2,fight,tlife<1,v_nav>0,sktest:守缺式,cdtime:亦枯亦荣<0.2]亦枯亦荣

　　/var [explast:亦枯亦荣,0;v_nav]v_nav

　　--擒龙诀回豆的判定，如果擒龙诀buff存在的时候，擒龙诀buff的时间接近回豆的时间了，预判回1豆

　　/var [(bufftime:擒龙诀;18)<17,(bufftime:擒龙诀*10)%15] v_擒龙诀回豆倒计时

　　/if [v_擒龙诀回豆倒计时,( v_擒龙诀回豆倒计时<0.3),v_nav+1]--时间限制为0-1

　　/if [!v_added]--时间段内只加一次

　　/var [v_nav+1] v_nav

　　/var [true] v_added

　　/end

　　/else--时间段外重置加法判定变量

　　/var [false] v_added

　　/end

　　--★有GCD技能部分★

　　--点了众嗔奇穴的情况下，众嗔快断了的时候，补一个守缺

　　/skill [cdtime:守缺式<0.2,sklv:6596=1,(bufftime:众嗔;3)<2]守缺式

　　--优先守缺

　　/skill [v_守缺优先=3,cdtime:守缺式<0.2,buff:天鼓雷音阵,bufftime:天鼓雷音五阵<=1.5]守缺式

　　--上述技能结束之后，如果禅那大于等于3，优先拿云，之后韦陀。

　　--判断拿云后的一豆

　　/skill [!explast:韦陀献杵,v_nav>=3,tlife<=0.3,cdtime:拿云式<0.2]拿云式

　　/if [explast:拿云式,recipe:《龙爪功·拿云式》人偶图残页]

　　/var [nowtime] v_终结技释放标志

　　/end

　　/skill [!v_禁断灭,!explast:拿云式,v_nav>=3,tlife>0.3,cdtime:韦陀献杵<0.2]韦陀献杵

　　--判断韦陀后的一豆

　　/if [explast:韦陀献杵,recipe:《罗汉棍法·韦陀献杵》人偶图残页]

　　/var [nowtime] v_终结技释放标志

　　/end

　　--★★非预判版宏★★

　　/else

　　--★无GCD技能部分★

　　--无相诀之后不开爆发

　　/if [!expcast:无相诀]

　　--优先金刚怒目，后擒龙诀

　　/skill [nav=3,fight,tlife<1,sktest:守缺式,cdtime:金刚怒目<0.2,nobuff:1919,(v_金刚怒目=1;tlife>0.3)]金刚怒目

　　--GCD在读到接近一半的时候，再开擒龙诀，此后，每次刷到一半就会回一个豆，判定可以很精确

　　--请勿随意调整GCD的判定数据，否则会造成预判不准在非三豆的情况下打韦陀、拿云

　　--1【智能爆发】如果CWbuff的内置CD小于20秒，擒龙好了，则等待buff触发再打擒龙/雷buff的内置CD小于20秒，擒龙好了，则等待buff触发再打擒龙

　　--2【自动爆发】直接使用擒龙诀

　　/if [!banskill:擒龙诀,cd0<0.9,cd0>0.5,fight,sktest:守缺式,cdtime:擒龙诀<0.2,!v_小怪判定,(v_爆发模式=2;v_爆发模式=1,(v_雷触发时间=0,v_CW触发时间=0;(nowtime-v_雷触发时间)-v_雷buff内置CD<-30;(nowtime-v_CW触发时间)-v_CWbuff内置CD<-15))]

　　/skill [nav=1,fight,cdtime:亦枯亦荣<0.2,nowtime-(v_终结技释放标志;0)<1.5] 亦枯亦荣,擒龙诀

　　/skill [nav<=1]擒龙诀

　　/end

　　--擒龙诀之后，如果金刚怒目好了，优先金刚怒目

　　/skill [nav=3,fight,tlife<1,sktest:守缺式,cdtime:金刚怒目<0.2,nobuff:1919,(v_金刚怒目=1;tlife>0.3)]金刚怒目

　　/end

　　--有捕风式buff或者GCD大于0.5秒的，并且可以释放捉影式的时候，释放捉影式

　　/skill [!tplate:地字一号|隐元会暗杀者,(nav<3,buff:捕风式;gcd>0.5,cdtime:捉影式<0.2)] 捉影式

　　--缺蓝就不等擒龙诀，直接开亦枯亦荣了

　　/skill [mana<0.2,fight,tlife<1,nav>0,sktest:守缺式,cdtime:亦枯亦荣<0.2]亦枯亦荣

　　--★有GCD技能部分★

　　--点了众嗔奇穴的情况下，众嗔快断了的时候，补一个守缺

　　/skill [cdtime:守缺式<0.2,sklv:6596=1,(bufftime:众嗔;3)<2]守缺式

　　--优先守缺

　　/skill [v_守缺优先=3,cdtime:守缺式<0.2,buff:天鼓雷音阵,bufftime:天鼓雷音五阵<=1.5]守缺式

　　--上述技能结束之后，如果禅那大于等于3，优先拿云，之后韦陀。

　　--判断拿云后的一豆

　　/skill [!explast:韦陀献杵,nav>=3,tlife<=0.3,cdtime:拿云式<0.2]拿云式

　　/if [explast:拿云式,recipe:《龙爪功·拿云式》人偶图残页]

　　/var [nowtime] v_终结技释放标志

　　/end

　　/skill [!v_禁断灭,!explast:拿云式,nav>=3,tlife>0.3,cdtime:韦陀献杵<0.2]韦陀献杵

　　--判断韦陀后的一豆

　　/if [explast:韦陀献杵,recipe:《罗汉棍法·韦陀献杵》人偶图残页]

　　/var [nowtime] v_终结技释放标志

　　/end

　　/end

　　--★打豆技能部分★

　　--优先守缺，然后横扫，然后普渡,恒河劫沙，然后使用捕风

　　/skill [v_守缺优先=2; v_守缺优先=4,nav<=1]守缺式

　　/skill [fight,tar,(sktest:普渡四方;distance<=5;(tplate:傀儡·天,dis<=6))] 横扫六合

　　/skill [v_守缺优先=1]守缺式

　　/skill 普渡四方

　　/skill 恒河劫沙

　　/skill [(!sktest:守缺式;cdtime:守缺式>1.2),tar]捕风式

再逛逛>>